STKResonate
Prev | Orchestra Opcodes and Operators | Next

## STKResonate

STKResonate — STKResonate is a noise driven formant filter.

## Description

Plugin opcode in stkopd.

STKResonate is a noise driven formant filter. This instrument contains a noise source, which excites a biquad resonance filter, with volume controlled by an ADSR.

## Syntax

    asignal STKResonate ifrequency, iamplitude, [kfreq, kv1[, kpole, kv2[, knotch, kv3[, kzero, kv4[, kenv, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kfreq -- controller 2, frequency of resonance. Value range of kv1 is 0-127.

kpole -- controller 4, pole radii. Value range of kv2 is 0-127.

knotch -- controller 11, notch frequency. Value range of kv3 is 0-127.

kzero -- controller 1, zero radii. Value range of kv4 is 0-127.

kenv -- controller 128, gain of envelope. Value range of kv5 is 0-127.

| Note

The code for this opcode is taken directly from the Resonate class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). Both the controller numbers and the controller values are krate variables. However, during a performance, normally the controller numbers stay fixed while the corresponding controller values may change at any time. The order of the controller pair is arbitrary, as long as they are after iamplitude. Also, it is not needed that all controller pairs are used.

## Examples

Here is an example of the STKResonate opcode. It uses the file STKResonate.csd.

Example 987. Example of the STKResonate opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKResonate.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1 ; frequency and amplitude of STKResonate have no effect

    kv2	=	p4				;pole radii
    kv1	line	100, p3, 0			;resonance freq + notch freq
    kv3	=	kv1
    asig	STKResonate 1, 1, 2, kv1, 4, kv2, 1, 10, 11, kv3, 128, 100
    asig	=	asig * .3			;too loud
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 1 0
    i 1 + . >
    i 1 + . >
    i 1 + . >
    i 1 + . 120
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKPlucked | Home | STKRhodey