chnmix
Prev | Orchestra Opcodes and Operators | Next

## chnmix

chnmix — Writes audio data to the named software bus, mixing to the previous output.

## Description

Adds an audio signal to a channel of the named software bus. Implies declaring the channel with imode=2 (see also chn_a).

## Syntax

    chnmix aval, Sname

## Initialization

Sname -- a string that indicates which named channel of the software bus to write.

## Performance

aval -- the audio signal to write at performance time.

## Examples

Here is an example of the chnmix opcode. It uses the file chnmix.csd.

Example 135. Example of the chnmix opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o chnmix.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    ;Example by Joachim Heintz
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

      instr 1; send i-values
              chnset    1, "sio"
              chnset    -1, "non"
      endin

      instr 2; send k-values
    kfreq     randomi   100, 300, 1
              chnset    kfreq, "cntrfreq"
    kbw       =         kfreq/10
              chnset    kbw, "bandw"
      endin

      instr 3; send a-values
    anois     rand      .1
              chnset    anois, "noise"
     loop:
    idur      random    .3, 1.5
              timout    0, idur, do
              reinit    loop
     do:
    ifreq     random    400, 1200
    iamp      random    .1, .3
    asig      oscils    iamp, ifreq, 0
    aenv      transeg   1, idur, -10, 0
    asine     =         asig * aenv
              chnset    asine, "sine"
      endin

      instr 11; receive some chn values and send again
    ival1     chnget    "sio"
    ival2     chnget    "non"
              print     ival1, ival2
    kcntfreq  chnget    "cntrfreq"
    kbandw    chnget    "bandw"
    anoise    chnget    "noise"
    afilt     reson     anoise, kcntfreq, kbandw
    afilt     balance   afilt, anoise
              chnset    afilt, "filtered"
      endin

      instr 12; mix the two audio signals
    amix1     chnget     "sine"
    amix2     chnget     "filtered"
              chnmix     amix1, "mix"
              chnmix     amix2, "mix"
      endin

      instr 20; receive and reverb
    amix      chnget     "mix"
    aL, aR    freeverb   amix, amix, .8, .5
              outs       aL, aR
      endin

      instr 100; clear
              chnclear   "mix"
      endin

    </CsInstruments>
    <CsScore>
    i 1 0 20
    i 2 0 20
    i 3 0 20
    i 11 0 20
    i 12 0 20
    i 20 0 20
    i 100 0 20
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Istvan Varga
2006

Prev | Up | Next
chnget | Home | chnparams