STKWhistle
Prev | Orchestra Opcodes and Operators | Next

## STKWhistle

STKWhistle — STKWhistle produces whistle sounds.

## Description

Plugin opcode in stkopd.

STKWhistle produces (police) whistle sounds. It uses a hybrid physical/spectral model of a police whistle (a la Cook).

## Syntax

    asignal STKWhistle ifrequency, iamplitude, [kmod, kv1[, knoise, kv2[, kfipfreq, kv3[, kfipgain, kv4[, kvol, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kmod -- controller 2, blowing frequency modulation. Value range of kv1 is 0-127.

knoise -- controller 4, noise gain. Value range of kv2 is 0-127.

kfipfreq -- controller 11, fipple modulation frequency. Value range of kv3 is 0-127.

kfipgain -- controller 1, fipple modulation gain. Value range of kv4 is 0-127.

kvol -- controller 128, volume. Value range of kv5 is 0-127.

| Note

The code for this opcode is taken directly from the Whistle class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). Both the controller numbers and the controller values are krate variables. However, during a performance, normally the controller numbers stay fixed while the corresponding controller values may change at any time. The order of the controller pair is arbitrary, as long as they are after iamplitude. Also, it is not needed that all controller pairs are used.

## Examples

Here is an example of the STKWhistle opcode. It uses the file STKWhistle.csd.

Example 996. Example of the STKWhistle opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKWhistle.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifrq	=	p4
    kv1	line	p5, p3, p6				;Blowing Frequency Modulation
    kv3	=	p7					;Fipple Modulation Frequency

    asig	STKWhistle cpspch(p4), 1, 4, 20, 11, kv3, 1, 100, 2, kv1, 128, 127
    asig	=	asig*.7				;too loud
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 .5 9.00 100 30 30
    i 1 1 3  9.00 100  0 20
    i 1 4.5 . 9.00 1  0 100
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKVoicForm | Home | STKWurley