STKHevyMetl
Prev | Orchestra Opcodes and Operators | Next

## STKHevyMetl

STKHevyMetl — STKHevyMetl produces metal sounds.

## Description

Plugin opcode in stkopd.

STKHevyMetl produces metal sounds, using FM synthesis. It uses 3 cascade operators with feedback modulation, also referred to as algorithm 3 of the TX81Z.

## Syntax

    asignal STKHevyMetl ifrequency, iamplitude, [kmod, kv1[, kcross, kv2[, klfo, kv3[, klfodepth, kv4[, kadsr, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kmod -- controller2, total modulator index. Value range of kv1 is 0-127.

kcross -- controller 4, crossfade of modulator. Value range of kv2 is 0-127.

klfo -- controller 11, speed of low-frequency oscillator. Value range of kv3 is 0-127.

klfodepth -- controller 1, depth of low-frequency oscillator. Value range of kv4 is 0-127.

kadsr -- controller 128, ADSR 2 and 4 target. Value range of kv5 is 0-127.

| Note

The code for this opcode is taken directly from the HevyMetl class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). Both the controller numbers and the controller values are krate variables. However, during a performance, normally the controller numbers stay fixed while the corresponding controller values may change at any time. The order of the controller pair is arbitrary, as long as they are after iamplitude. Also, it is not needed that all controller pairs are used.

## Examples

Here is an example of the STKHevyMetl opcode. It uses the file STKHevyMetl.csd.

Example 981. Example of the STKHevyMetl opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKHevyMetl.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    ifrq	=	p4
    kv1	line	p5, p3, p6				;Total Modulator Index
    kv2	line	p7, p3, 0				;Modulator Crossfade

    asig	STKHevyMetl cpspch(ifrq), 1, 2, kv1, 4, kv2, 11, 0, 1, 100, 128, 40
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 7  8.05 100 0  100
    i 1 3 7   9.03 20 120  0
    i 1 3 .5  8.05 20 120  0
    i 1 4 .5  9.09 20 120  0
    i 1 5 3   9.00 20 120  0

    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

STKWurley.

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKFMVoices | Home | STKMandolin